import Quickshell
import Quickshell.Wayland
import QtQuick
import QtQuick.Layouts
import "../../config"

PanelWindow {
    id: bar

    anchors {
        top: true
        left: true
        right: true
    }
    implicitHeight: Appearance.barHeight
    exclusiveZone: implicitHeight
    color: "transparent"

    // Narrow screen (laptop): shorten the left-side free-text labels so they
    // don't crowd the centre group.
    readonly property bool compact: width < Appearance.compactBarWidth

    WlrLayershell.layer: WlrLayer.Top
    WlrLayershell.namespace: "quickshell:bar"

    Rectangle {
        anchors.fill: parent
        color: Colors.background
    }

    RowLayout {
        anchors {
            left: parent.left
            verticalCenter: parent.verticalCenter
            leftMargin: Appearance.spacing
        }
        spacing: Appearance.spacing
        Workspaces { screen: bar.screen }
        MediaPlayer { barWindow: bar; compact: bar.compact }
        ActiveWindow { compact: bar.compact }
    }

    RowLayout {
        anchors.centerIn: parent
        spacing: Appearance.spacing
        Weather { barWindow: bar }
        Clock {}
        SystemUpdate { barWindow: bar }
    }

    RowLayout {
        anchors {
            right: parent.right
            verticalCenter: parent.verticalCenter
            rightMargin: Appearance.spacing
        }
        spacing: Appearance.spacing
        PinnedTray {}
        TailscaleIndicator { barWindow: bar }
        VpnIndicator { barWindow: bar }
        NetworkIndicator { barWindow: bar }
        BluetoothIndicator { barWindow: bar }
        Volume { barWindow: bar }
        BatteryIndicator { barWindow: bar }
        PowerButton { barWindow: bar }
    }
}